VECTORES EN EL ESPACIO

 PRODUCTO ESCALAR, VECTORIAL Y MIXTO DE VECTORES

Con la hoja de cálculo Excel podemos hallar automáticamente el producto escalar, vectorial y mixto de vectores en el espacio en función de sus coordenadas, como se muestra en el siguiente ejemplo:

CONSTRUCCIÓN DE LA HOJA

Abre hoja nueva de Excel e introduce las coordenadas de tres vectores u, v, w en las celdas B2 a D4.

Para evitar las expresiones con referencias a celdas vamos a asignar un nombre  a cada una. Sitúa el cursor en B2 (donde figura la coordenada ux del vector u) y en la barra de menús elige Insertar + Nombre + Definir. Escribe ux en la primera línea y observa que en la parte inferior aparece la referencia de la celda. Has asignado un nombre a la celda B2 y ahora podrás escribir ux en vez de B2 en cualquier expresión. Repítelo para el resto de coordenadas de u, v y w.

Rellena el resto de la hoja de la siguiente forma:

	A	B	C	D	E	F
1	VECTORES					MODULOS
2	u=>	3	2	4	|u|  =	=RAIZ(ux^2+uy^2+uz^2)
3	v=>	-1	2	3	|v|  =	=RAIZ(vx^2+vy^2+vz^2)
4	w=>	3	-5	-1	|w| =	=RAIZ(wx^2+wy^2+wz^2)
5
6	u v =	=ux*vx+uy*vy+uz*vz			P.ESCALAR	=ABS(B6)
7	u x v =	=uy*vz-uz*vy	=-ux*vz+uz*vx	=ux*vy-uy*vx	P. VECTORIAL	=RAIZ(B7^2+C7^2+D7^2)
	u v w =	=MDETERM(B2:D4)			P. MIXTO	=ABS(B8)

Observa las
expresiones del producto escalar, vectorial y mixto en función de las coordenadas de los vectores.

Repara, en particular, en las coordenadas del producto vectorial.

En el caso del producto mixto se obtiene el determinante con la función MDETERM.

El módulo de los productos escalar y mixto se refiere al valor absoluto al tratarse de números.

Puedes mejorar el aspecto de la hoja con algún fondo coloreado que permita distinguir los vectores y los diferentes resultados.

PRÁCTICAS

• Introduce en la hoja las coordenadas de los siguientes vectores u, v y w y obtén los correspondientes productos escalar, vectorial y mixto, así como sus respectivos módulos.

u:=[1, 2, 1]                              v:=[-1, 1, -1]                           w:=[0, 3, 0]

u:=[0, 0, 0]                              v:=[-1, 1, -2]                           w:=[0, 2, -1]

u:=[123, 675, 432]                  v:=[-317, 401, -212]               w:=[10, 27, -19]

u:=[3,51; 1,37; 2,41]               v:=[-1,23; 2,31; -7,22]            w:=[0,11; 2,43; -1,06]

• Para  tres vectores u,v y w cualesquiera halla los siguientes productos deduciendo de los resultados las correspondientes propiedades:

Producto escalar:                     uv          vu        uu        u0        ( vector 0(0,0,0)  )

Producto vectorial:                   u x v       v x u     u x u     u x 3u   ( toma como vector v el triple de u)

                                               3u x v

Producto mixto:                       (u,v,w)   (v,u,w)

• Considera los vectores i=[1, 0, 0],  j=[0, 1, 0]  y  k=[0, 0, 1] halla los siguientes productos vectoriales:

i x j                          i x k                  j x k                         j x i                    k x j          k x i

Ten en cuenta en cada caso qué vector debes introducir en la hoja como u y como v.

AMPLIACIÓN

Amplia la hoja para hallar la suma de dos vectores y el producto de un escalar k por un vector. Para ello inserta:

k=        en A5  ( e introduce un número en B5)

u+v=    en A9   (y las expresiones correspondientes en B9,C9 y D9)

ku=      en A10(y las expresiones correspondientes en B10,C10 y D10)

Añade una fila para hallar el ángulo formado por dos vectores u y v ( los introducidos en las filas 2 y 3).

En la celda B11 debes introducir la expresión

=ACOS(F6/(F2*F3))*180/PI()

La función ACOS halla el arco coseno, F6/(F2*F3) divide el producto escalar por el producto de los módulos, y *180/pi() multiplica el resultado por 180 y lo divide por p para pasar el ángulo de radianes ( resultado por defecto de ACOS) a grados.

ORTONORMALIZACIÓN DE VECTORES

¿Cómo conseguir una base ortonormal a partir de dos vectores (no paralelos)?

Considera los vectores u(1,2,2) y v(5,1,0). Vamos a construir una base de tres vectores ortogonales y de módulo 1. Lo hacemos en dos fases: ortogonalización y normalización.

Como primer vector u’ tomamos el mismo vector u y como segundo vector v’ el producto vectorial de u y v que sabemos que es perpendicular ( u ortogonal) a ambos y por tanto a u’. Como tercer vector w’ tomamos el producto vectorial de u’ y v’. De esta forma hemos conseguido tres vectores perpendiculares entre sí.

Para conseguir que el módulo sea la unidad basta dividir las tres coordenadas de cada vector por el módulo.

Puedes hacerlo automáticamente como se muestra a continuación:

La construcción de la hoja se muestra en la siguiente tabla.

	A	B	C	D
1	VECTORES (iniciales)
2	u=>	1	2	2
3	v=>	5	1	0
4	ORTOGONALIZACIÓN
5	u'=	=B2	=C2	=D2
6	v'=	=C2*D3-D2*C3	=-(B2*D3-D2*B3)	=B2*C3-C2*B3
7	w'=	=C5*D6-D5*C6	=-(B5*D6-D5*B6)	=B5*C6-C5*B6
8	NORMALIZACIÓN
9	u''=	=B5/RAIZ(B5^2+C5^2+D5^2)	=C5/RAIZ(B5^2+C5^2+D5^2)	=D5/RAIZ(B5^2+C5^2+D5^2)
10	v''=	=B6/RAIZ(B6^2+C6^2+D6^2)	=C6/RAIZ(B6^2+C6^2+D6^2)	=D6/RAIZ(B6^2+C6^2+D6^2)
11	w''=	=B7/RAIZ(B7^2+C7^2+D7^2)	=C7/RAIZ(B7^2+C7^2+D7^2)	=D7/RAIZ(B7^2+C7^2+D7^2)